<?xml version="1.0" encoding="utf-8"?>
<menu menuOpen="1" moveonMouseOver="false">
<item Ititle="home" IcontentType="image/swf" IcontentData="image2.jpg"/>
<item Ititle="about" IcontentType="text" IcontentData="Our company is based on UK! Know how we have born!; Click here"/>
<item Ititle="Products" IcontentType="image/swf" IcontentData="image5.jpg"/>
<item Ititle="Services" IcontentType="image/swf" IcontentData="item2.swf"/>
<item Ititle="Contact" IcontentType="image/swf" IcontentData="image1.jpg"/>
</menu>

//импорт классов tweenlite
import gs.TweenLite;
import gs.easing.*;

var MENU_ARRAY:Array; //используем для хранения данных пунктов меню
var OPENED_MENU:int; //чтобы информировать, какое меню должно быть открыто при старте
var MOVE_ON_MOUSE_OVER:Boolean=false; //имя говорит само за себя
var xmlLoader:URLLoader; //загрузчик xml

loadXML("menu.xml"); //загружаем xml

function loadXML(Uri:String):void {
xmlLoader = new URLLoader();
xmlLoader.addEventListener(Event.COMPLETE, onComplete);
xmlLoader.addEventListener(IOErrorEvent.IO_ERROR, onError);
xmlLoader.load(new URLRequest(Uri));
}

function onError(evt:ErrorEvent):void {
trace("cannot load xml file");
}

function onComplete(evt:Event):void {
//читаем и загружаем xml в массив, распарсим его, используя prepareMenu
MENU_ARRAY=prepareMenu(xmlLoader.data.toString());
placeItemsOnStage(); //размещаем все требуемые пункты на сцене.
}

function placeItemsOnStage():void {
var pos:Number=0;
//определяем свойства контейнера
menuContainer.x=0;
menuContainer.y=0;

for(var c:int=0; c<MENU_ARRAY.length; c++) {
var it:menuItem = new menuItem; //загружаем menuItem, поскольку он экспортируется в AS, мы можем использовать его здесь
it.x=c*27; //ширина его серого бордюра
it.y=0; //помещаем наверх
it.id="Item-"+c; //id для menuItem
it.name="Item-"+c; //имя для menuItem
it.posX=pos; //фактическая позиция, используется, чтобы открывать и знать позицию
it.itemLabel.text=String(MENU_ARRAY[c].Ititle).toUpperCase(); //загружаем метку label, переводим в заглавные буквы
it.addEventListener(MouseEvent.CLICK, onMouseClick); //добавляем слушатель mouse click
if(MOVE_ON_MOUSE_OVER==true) it.addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
//если сконфигурировано, загружаем событие mouse over
it.useHandCursor=true;  //используем курсор hand
it.buttonMode=true; //buttonMode
it.itemText.visible=false; //спрячем текстовое поле
menuContainer.addChild(it); //добавим пункт меню как child

if(String(MENU_ARRAY[c].IcontentType)=="image/swf")    { //проверим контент и зарузим все, что соответствует ему
var ldr:Loader = new Loader();
ldr.x=27;
ldr.y=0;
it.addChild(ldr);
ldr.load(new URLRequest(MENU_ARRAY[c].IcontentData.toString()));
}
else if(String(MENU_ARRAY[c].IcontentType)=="text") {
it.itemText.visible=true;
it.itemText.text=MENU_ARRAY[c].IcontentData.toString();
}
pos+=27; //позиция x следующего menuItem
}

//поместим  маску в место....
masker.width=(MENU_ARRAY.length*27+325)
masker.height=menuContainer.height;
masker.x=0;
masker.y=0;

moveItem(OPENED_MENU-1); //открываем меню, сконфигурированное в  XML

}

function onMouseOver(evt:MouseEvent):void {
if(evt.target.name.toString()=="buttonBack") prepareMove(evt)
}

function prepareMove(evt:MouseEvent):void {
var targetName:String = evt.currentTarget.name.toString(); //получим menuItem
var temp:Array = targetName.split("-"); //разделим его имя: Item-x
var itemNumber:int=(temp[1]); //получили номер пункта
moveItem(itemNumber); //двигаем его
}

function onMouseClick(evt:MouseEvent):void {
if(evt.target.name.toString()=="buttonBack")  prepareMove(evt); //действие мыши произошло на buttonBack
else trace("Item "+evt.currentTarget.name+" clicked!"); //действие мыши произошло в области гармошки
}

function moveItem(num:int):void {
var itemToMove:menuItem=menuContainer.getChildByName("Item-"+String(num)) as menuItem;
//получим детку menuItem
for(var m=0;m<MENU_ARRAY.length;m++) //двигаем один за одним на новую позицию
{
var tempMc = menuContainer.getChildByName("Item-"+m);
if(tempMc.x > itemToMove.x) TweenLite.to(tempMc, 1, {x:((tempMc.posX) + itemToMove.width-27), ease:Quart.easeOut}); //смотрим информацию об этом в tweenLite .
else if(tempMc.x <= itemToMove.x) TweenLite.to(tempMc, 1, {x:(tempMc.posX), ease:Quart.easeOut});
}
}

function prepareMenu (XMLData:String):Array
{
//убедимся, что данные пришли в XML
var menuXML:XML = new XML(XMLData);
//на всякий случай
menuXML.ignoreWhitespace = true;

//получим элементы XML для пунктов
var XMLItems = menuXML.descendants("item");

//загружаем все пункты в массив
var itemsArray:Array = new Array();
var itemObj:Object;
for(var i in XMLItems)
{
itemObj=new Object();
itemObj.Ititle=XMLItems[i].@Ititle;
itemObj.IcontentType=XMLItems[i].@IcontentType;
itemObj.IcontentData=XMLItems[i].@IcontentData;
itemObj.itemID="menu"+i;
itemsArray.push(itemObj);
}
OPENED_MENU=menuXML.@menuOpen; //получаем меню для открытия.
MOVE_ON_MOUSE_OVER=(menuXML.@moveonMouseOver.toString()=="true" ? true : false); //получаем опцию для загрузки : открыта или нет mouseOver
return itemsArray;
}

//конец.